icloud

Porque el fichero que se crea hoy es con fecha de hoy... internamente, en los metatados, sí conserva la fecha original en la que se tomó la foto.

Con este script puedes convertir todos los nombres en su correspondiente fecha (de captura) en "fecha+tiempo+serial+extension" rápidamente.

Lo copias y lo pegas en un documento nuevo del Editor de Scripts, lo ejecutas y seleccionas todos los ficheros que quieras renombrar.

set serial to 1
set pix_list to choose file with prompt "Choose an Image" with multiple selections allowed
set addzeros to length of ((count of pix_list) as string)
tell application "Image Events"
  repeat with _pix in pix_list
  try
  set this_image to open alias (_pix as text)
  
  tell this_image
  repeat with i from 1 to the count of metadata tags
  set this_tag to metadata tag i
  set the tag_name to the name of this_tag
  set the tag_value to the value of this_tag
  if tag_name = "creation" then
  set newName to my replaceText(" ", "-", my replaceText(":", "", tag_value))
  end if
  end repeat
  end tell
  
  tell application "Finder"
  set extension to name extension of _pix
  set izena to name of _pix
  set finalizena to newName & "-" & my add_leading_zeros(serial, addzeros) & "." & extension
  set the name of _pix to finalizena
  end tell
  end try
  set serial to serial + 1
  end repeat
end tell

on replaceText(find, replace, subject)
  set prevTIDs to text item delimiters of AppleScript
  set text item delimiters of AppleScript to find
  set subject to text items of subject
  set text item delimiters of AppleScript to replace
  set subject to "" & subject
  set text item delimiters of AppleScript to prevTIDs
  return subject
end replaceText

on add_leading_zeros(this_number, max_leading_zeros)
  return text (max_leading_zeros * -1) thru -1 of ("00000000000000000" & this_number)
end add_leading_zeros