F: Wie kann ich rausfinden, in welchen Alben sich ein Foto überall befindet?

In meiner Library habe ich über 50.000 Fotos, die ich in diverse Unterordner (Alben) verteilt habe. Oft habe ich sie in mehrere Alben verlinkt, weil sie logisch zu unterschiedlichen Themen passen.  Manchmal rutschen sie beim Verschieben/Zuordnen auch versehentlich in einen falsches Album. Im Nachhinein ist es für mich aber nicht möglich herauszufinden, in welchen Alben sich die Foto dann überall befinden. Unter "Informationen" gibt es keine Info, welchen Alben das Foto überall zugeordnet ist. Gibt es einen Trick, um das raus zu bekommen?

 

Gruß Rüdi

Gepostet am 07.05.2017 07:56

  • Hilfreiche Antworten
  • Alle Antworten
  • von Leonie,

     Leonie 07.05.2017 08:53 als Antwort auf Lazyrudi
    Level 10 Stufe 10 (119.601 Punkte)
    expertise.macosx
    Mac OS X
    07.05.2017 08:53 als Antwort auf Lazyrudi

    Ja, Fotos hat leider kein Kommando, um die Alben zu finden, in denen ein Foto ist.

    Damit ich in der Information für ein Foto sehen kann, in welchem Album es ist, füge ich immer ein Schlagwort mit dem Namen des Albums zu. Das erscheint in der Information. Und ich verwende dann einfach ein Intelligentes Album mit der Regel "Schlagwort ist 'Bär'" oder ähnlich.

     

    Für Fotos in Standardalben kannst du ein Apple Script verwenden, das Jacques Rioux's geschrieben hat.

    Ich habe es hier in einem Benutzer-Tipp veröffentlicht (auf englisch, werde es bei Gelegenheit übersetzen).

    https://discussions.apple.com/docs/DOC-9261

    07.05.2017 08:53

  • von Leonie,

     Leonie 07.05.2017 09:31 als Antwort auf Leonie
    Level 10 Stufe 10 (119.601 Punkte)
    expertise.macosx
    Mac OS X
    07.05.2017 09:31 als Antwort auf Leonie

    Hier ist eine Version von Jacques Skript. Ich habe ein paar Fehlerabfragen eingebaut, um es etwas sicherer zu machen.

    Um das Skript zu verwenden öffne den Script Editor - er ist in Programme > Dienstprogramme

     

    • Kopiere das Skript in den Script Editor, sichere es.
    • Wähle des Foto in Fotos aus, für das Du die Alben wissen willst.
    • Dann drücke den "Run" Knopf im Skript Editor.
    • Du kannst das Skript auch mit "Ablage > Export" als Programm sichern lassen (Format: compiled version). Dan kann es dem Dock hinzugefügt werden und von da gestartet.

    Das Skript wird kurz anzeigen, nach welchem Foto es sucht, dann erscheint ein Dialogfenster mit der Liste der Alben. das dauert ziemlich lange für eine grosse Mediathek. Die liste der Alben wird im Clipboard gespeichert, so dass Du sie mit "Paste" irgendwo sichern kannst.

     

    ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎

    --- Ab hier kopieren ---

    -- Jacques Rioux's script  https://discussions.apple.com/message/29601534#29601534

    -- modified by leonie

     

    -- Select the photo in Photos, then run this script by pressing the "Run" button in the script editor or from the scripts menu.

     

    tell application "Photos"

      activate

      -- Add the photo you want to search for to a top level album as the first item in the album

     

      set resultcaption to "Searching for: "

      try

     

      set sel to selection

      if sel is {} then error "The selection  is empty" -- no selection

     

      on error errTexttwo number errNumtwo

      display dialog "No photos selected " & errNumtwo & return & errTexttwo

      return

      end try

     

      set imagename to "unknown filename"

      try

      set target to item 1 of sel -- the image to seach for

      tell target

      set imagename to the filename of target

      end tell

      on error errTexttwo number errNumtwo

      display dialog "Cannot get the filename of the first image: " & errNumtwo & return & errTexttwo

      end try

      set resultcaption to (resultcaption & imagename)

    end tell

     

    try

      display alert resultcaption buttons {"Cancel", "OK"} as informational giving up after 2

    on error errText number errNum

      if (errNum is equal to -128) then

      -- User cancelled.

      return

      end if

    end try

    -- From Jacques Rioux's script:

    tell application "Photos"

      -- set sel to selection

      if sel is {} then return -- no selection

      try

      set thisId to id of item 1 of sel

      on error errText number errNum

      display dialog "Error: cannot get the image ID" & errNum & return & errText & "Trying again"

     

      try

      delay 2

      set thisId to id of item 1 of sel

      on error errTexttwo number errNumtwo

      display dialog "Skipping image due to repeated error: " & errNumtwo & return & errTexttwo

      error "giving up"

      return

      end try --second attempt

      end try

     

      set theseNames to {}

      try

      set theseNames to name of (albums whose id of media items contains thisId)

      on error errText number errNum

      display dialog "Error: cannot get the albums" & errNum & return & errText & "Trying again"

      try

      delay 2

      set theseNames to name of (albums whose id of media items contains thisId)

      on error errTexttwo number errNumtwo

      display dialog "Skipping image due to repeated error: " & errNumtwo & return & errTexttwo

      error "giving up"

      return

      end try

      end try

    end tell

     

    if theseNames is not {} then

      set {oTid, text item delimiters} to {text item delimiters, return}

      set {t, text item delimiters} to {theseNames as string, oTid}

      -- return oTid

    else

      set t to "No album"

    end if

    activate

     

    set resultcaption to resultcaption & ", found it in these albums:

    " & t as string

    set the clipboard to resultcaption

    display dialog resultcaption buttons {"OK"} default button "OK" -- you can press the Enter key or the return Key to close the dialog

    return resultcaption -- léonie


     

    --- bis hier kopieren

    -- ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎ ✂︎

    07.05.2017 09:31

  • von Lazyrudi,

     Lazyrudi 07.05.2017 18:02 als Antwort auf Leonie
    Level 1 Stufe 1 (12 Punkte)
    07.05.2017 18:02 als Antwort auf Leonie

    Hallo Leonie, tut mir leid, aber das ist mir eine Nummer zu hoch    Verstehe nur Bahnhof. Bin nur dummer Anwender, kein Programmierer. Die Bilder habe ich in diversen selbst generierten Ordnern abgelegt, also nicht gerade Foto-Standardordner. Jedem Foto ein Schlagwort zu geben wäre mir bei der Menge zu aufwändig. Über welchen Kanal könnte man denn Apple motivieren so eine Funktion in die Entwicklung des nächsten Update mit aufzunehmen? Die Daten der Verlinkung dürfte für Apple im Program problemlos ausgelesen und unter "Informationen" in einer Liste angezeigt werden können.

    07.05.2017 18:02

  • von Leonie,

     Leonie 07.05.2017 20:15 als Antwort auf Lazyrudi
    Level 10 Stufe 10 (119.601 Punkte)
    expertise.macosx
    Mac OS X
    07.05.2017 20:15 als Antwort auf Lazyrudi

    Du kannst das Formular für die Rückmeldungen über Fotos ausfüllen und die Verbesserung fordern.

    Siehe:   https://www.apple.com/feedback/photos.html

     

    Apple verspricht, dass alle Rückmeldungen aufmerksam gelesen werden.

    07.05.2017 20:15

  • von Leonie,Hilfreich

     Leonie 19.05.2017 15:33 als Antwort auf Leonie
    Level 10 Stufe 10 (119.601 Punkte)
    expertise.macosx
    Mac OS X
    19.05.2017 15:33 als Antwort auf Leonie

    19.05.2017 15:33

  • von Lazyrudi,

     Lazyrudi 19.05.2017 15:35 als Antwort auf Leonie
    Level 1 Stufe 1 (12 Punkte)
    19.05.2017 15:35 als Antwort auf Leonie

    Supi, hat geklappt. Vielen Dank.

     

    Es wäre natürlich schön, wenn Apple das standardmäßig bei den Infos mit anzeigen würde, aber so kann ich mir zumindest weiterhelfen.

     

    Vielen, vielen Dank!!!    

     

    Gruß Rüdi

    19.05.2017 15:35

  • von Leonie,

     Leonie 19.05.2017 15:39 als Antwort auf Lazyrudi
    Level 10 Stufe 10 (119.601 Punkte)
    expertise.macosx
    Mac OS X
    19.05.2017 15:39 als Antwort auf Lazyrudi

    Prima! Gern geschehen

    19.05.2017 15:39