Feiertage von 2026 im Kalender nicht zu sehen

Welchen Feiertags - Kalender benutzt Du denn? Vermutlich wurde dieser noch nicht aktualisiert.

Solange die Feiertage im Kalender fehlen, benutze ich dieses Apple Script, dass die Daten der beweglichen Feste nach der Gauß'schen Osterregel ausrechnet - es funktioniert aber nur, wenn man das Datumsformat nicht mit Terminalkommandos verändert, sondern auf dem Standard für die Region läßt:

-- Compute the easter date using Gauss algorithm

set theDate to current date
set d to the day of theDate
set m to the month of theDate
set y to the year of theDate
set ts to the time string of theDate
set t to the time of theDate
set w to the weekday of theDate
set h to t / hours

display dialog "For which year do you want to know the easter date?:" default answer y buttons {"OK"} default button {"OK"}
--return the result
--copy the result as list to {the y, the button_pressed}
set y to the text returned of the result as number

if y < 1800 then return ("Sorry, the year must be in the range 1800:2200" & y)
if y < 1900 then
	set mm to 23
	set nn to n
else if y < 2100 then
	set mm to 24
	set nn to 5
else if y < 2200 then
	set mm to 24
	set nn to 6
else
	return "Sorry, the year must be in the range 1800:2200"
end if

set a to y mod 19
set b to y mod 4
set c to y mod 7
set d to (19 * a + mm) mod 30
set e to (2 * b + 4 * c + 6 * d + nn) mod 7

if 22 + d + e < 32 then
	set mon to 3 --March
else
	set mon to 4 --April
end if
if mon = 3 then
	set easterday to 22 + d + e
else
	set easterday to d + e - 9
	if easterday = 26 then set easterday to 19
	if (easterday = 25) and (d = 28) and (e = 6) and (a > 0) then set easterday to 19
end if
set ds to "" & easterday & "/" & mon & "/" & y
set rosemonday to the date string of ((date ds) - 48 * days)
set karfreitag to the date string of ((date ds) - 2 * days)
set easterdate to the date string of date ds
set pentacost to the date string of ((date ds) + 49 * days)
set ascension to the date string of ((date ds) + 39 * days)
set mayday to the date string of date ("1/5/" & y)
--set deutschEinheit to date ("3/10/" & y)
--set christmasEve to date ("24/12/" & y)

display dialog "Im Frühjahr " & y & " liegen die Feiertage wie folgt:
 Rosenmontag:  " & rosemonday & ",
 Karfreitag:  " & karfreitag & ",
 Ostern: 	" & easterdate & ",
 Himmelfahrt:  " & ascension & ", 
 Pfingsten:  " & pentacost & ",
 1. Mai: " & mayday buttons {"Danke"} default button {"Danke"}

Hier sind die Ergebnisse für 2026 und 2027, ohne Gewähr 😊



Keine Ahnung, Christine. Wie PreCognition schon angesprochen hat, gibt es von Apple keine Dokumentation, die einen festen Termin für die Kalendereinträge gesetzlichen Feiertage im kommenden Jahr verspricht. Das Aktualisieren des Feiertagskalenders für die Folgejahre scheint nicht die höchste Priorität zu haben. Ausserdem hängt der Termin für die bundesweiten oder regionalen gesetzlichen Feiertage ja auch von der Gesetzeslage ab. Manche Feiertage kommen unerwartet dazu und andere verschwinden wieder, siehe Reformationstag. Ist es sicherere bis kurz vor dem Jahreswechsel zu warten, ob es den Feiertag im nächsten Jahr wieder geben wird. Die Anzahl der gesetzlichen Festtage ist nach den letzten Wahlen ja auch schon wieder in der Diskussion.

Gut beobachtet, Richard. Den Tag der Arbeit habe ich als Test dabei 😃 - wenn intern die defaults Einstellungen für  AppleICUDateFormatStrings verstellt sind, sehe ich für den 1. Mai ein Datum in einem anderen Monat und weiß, das ich den Daten für die beweglichen Feiertage nicht trauen sollte, beispielsweise, wenn ich das Datumsformat umgestellt habe, so dass die Reihenfolge yyyy-mm-dd ist.

Ich liebe Apple Skript, aber das Arbeiten mit Objekten der Klasse Date ist riskant. Es fehlt ein Konstruktor, mit dem man sicher im Code ein bestimmtes Datum eingeben kann, das nicht von den Systemeinstellungen für die Region und Sprache abhängig ist. Wenn wir ein Datumsobjekt erzeugen, muss es über einen Date String initialisiert werden. Das Format für den Date String hängt von der Region ab, in der wir das Skript schreiben. Wenn ich ein Skript schreibe, werden beim ersten Öffnen die Datumsstrings meiner Region angepasst. Es ist schwer, ein Skript für Kalenderdaten zu schreiben, dass sowohl in den USA als auch in Deutschland mit den gängigen Landeseinstellungen läuft.

Ein Beispiel: Ich stelle in den Systemeinstellungen > Allgemein > Sprache und Region das Datumsformat 2025-08-19 (yyyy-mm-dd) ein. (Das verwende ich gerne, um das Datum beim Export in die Dateinamen von Fotos zu schreiben).

Wenn ich jetzt im Skript Editor das Datum für den 1.5.2000 als Date String eingebe, wie hier:

dann wird beim ersten Ausführen der String in ein einheitliches Format, aber mit falschem Datum gewandelt:

Deshalb meine Warnung, nur die voreingestellten Datumsformate zu verwenden.

Und ich schreibe in jedes Skript, das mit Datumsangaben rechnet, lieber auch in Testdatum rein, bei dem ich auf den ersten Blick erkenne, ob das Datum korrekt ist.

Und unabhängig vom Test sehe ich nebenbei auch, auf welchen Wochentag der 1.5. fällt.

-- Feiertage berechnen (bundesweit oder kirchlich)
set rosenmontag to easterdate - 48 * days
set gruendonnerstag to easterdate - 3 * days
set karfreitag to easterdate - 2 * days
set ostersonntag to easterdate
set ostermontag to easterdate + 1 * days
set himmelfahrt to easterdate + 39 * days
set pfingstsonntag to easterdate + 49 * days
set pfingstmontag to easterdate + 50 * days
set fronleichnam to easterdate + 60 * days
set tagderarbeit to date ("1/5/" & y)

-- Feste Feiertage in Bayern
set dreikoenige to date ("6/1/" & y)
set mariaeHimmelfahrt to date ("15/8/" & y)
set allerheiligen to date ("1/11/" & y)

Ups, das Augsburger Friedensfest (8. August, nur in der Stadt Augsburg) habe ich unterschlagen. 🫢

Liebe Grüße aus Bayern 😉

Programmieren bringt Spass, nicht wahr? 😊

Ich freue mich immer, wenn ich einen Anlass habe, noch einmal wieder etwas selbst zu programmieren.

Das Skript hatte ich übrigens schon vor einigen Jahren als Benutzertipp veröffentlicht: Ein Apple Script, um das Osterdatum und davon abhängige bewegliche Feiertage zu berechnen - Apple Community

Magst du deine Ergänzungen als Kommentar anhängen?

Nur eine Idee, Leonie

da AppleScript das ISO-Format [set tagderarbeit to (date (y & "-05-01"))] nicht direkt als date-String akzeptiert, empfiehlt es sich ggf., ein Datum mit current date als Vorlage zu nehmen und die Komponenten anzupassen:

set tagderarbeit to current date
set year of tagderarbeit to y
set month of tagderarbeit to May
set day of tagderarbeit to 1

-- Funktion zur einfachen Datumserstellung
on makeDate(dayNum, monthNum, yearNum)
	set d to current date
	set year of d to yearNum
	set month of d to monthNum
	set day of d to dayNum
	set time of d to 0
	return d
end makeDate

Das sollte absolut eindeutig sein und dürfte zuverlässig in jeder Region funktionieren.

Liebe Grüße! 🌺

Das ist eine gute Idee, danke, PreCognition, das habe ich in anderen Scripts auch schon so gemacht, wenn ich viel mit Daten rechnen mußte. Es it nur schade, dass wir uns selbst einen Konstruktor bauen müssen, der sicher in mehreren Ländern funktioniert.

Sehr gerne, Leonie,

es fühlt sich tatsächlich etwas altmodisch an, dass man im Jahr 2025 noch eigene Konstruktoren bauen muss, um mit international eindeutigen Formaten zu arbeiten – insbesondere, wenn man bedenkt, wie universell solche Formate heute im API- und Automatisierungs-Kontext sind.

Liebe Grüße! 🌺

Wahnsinn, Leonie. Ich trage mir die Feiertage manuell ein - analog. Hast du eine Idee dazu, warum das in einem Jahr funktionierst und im nächsten nicht?

Herzlichen Dank, Leonie,

Liebe Grüße! 🌺

Danke für die Ergänzungen, PreCognition !

Stimmt natürlich, wobei es ja die letzten ein/zwei Jahre funktioniert hat.