Bei mehren Fotos gleichzeitig das Datum ändern

testerer schrieb:

Moin,

alle gewünschten Bilder markieren (auswählen), dann oben in Menüleiste: "Bild/Datum und Uhrzeit anpassen" wählen und Datum ändern (genau wie es in der Hilfe steht).

Dieses Kommando ist dafür gedacht, das Datum aller ausgewählten Bilder gleichzeitig um denselben Zeitunterschied zu verschieben. wir können so das Datum korrigieren, wenn die Uhr in einer Kamera falsch eingestellt war, weil sie stehengeblieben ist, wenn die Batterie zu lange leer war. Das Kommando setzt das Datum aber nicht für die ausgewählten Bilder auf dasselbe Datum, sondern verschiebt die Daten nur für alle Bilder um ein festes Zeitintervall.

In Fotos fehlt leider ein Kommando, mit dem wir das Datum für mehrere Bilder in Stapelverarbeitung auf dasselbe Datum setzen können. In iPhoto gab es das noch, und ich vermisse die Stapelverarbeitung in iPhoto sehr.

Wenn es das Ziel sein sollte, beispielsweise für alte, gescannte Familienfotos für alle Bilder das Datum und die Uhrzeit auf dasselbe Datum zu setzen, brauchen wir Software von Drittanbietern, beispielsweise HoudahGeo.

Ich habe mir für solche Fälle ein Apple Script geschrieben: das Script steht hier (die Beschreibung ist allerdings auf englisch): Script: Batch Change the Date and Time to a Fixed Date

Um es zu benutzen,

• kopiere den Code unten in ein neues Fenster in Script Editor.
• Dann sammele alle Fotos, die dasselbe Datum erhalten sollen, in Fotos in einem Album, aufsteigend in der Reihenfolge, wie sie nach Datum sortiert werden sollen.
• Setze das Datum des ersten Bildes im Album, auf das Datum, dass alle Fotos erhalten sollen.
• Wähle alle Fotos im Album zusammen mit ⌘A aus und drücke in der Werkzeugleiste vom Scripteditor auf "run".

Scripteditor wird jetzt das Datum vom ersten Foto auf alle anderen ausgewählten Fotos kopieren, und dabei die Uhrzeit für jedes Foto gegenüber dem Vorgänger um eine Minute erhöhen, so dass die Fotos beim Sortieren nach der Uhrzeit ihre Reihenfolge behalten. Diese Zeit zwischen aufeinanderfolgenden Fotos kann im Skript in der ersten Zeile geändert werden. Setze timeIncrement auf 0, wenn das Datum exakt identisch sein soll.

-- ✄ ✄ ✄ ab hier kopieren ✄ ✄ ✄ ✄

(* Batch change the time of selected photos all at once 

How to use this script:
- Collect all photos you want to set to the same time in an album 
- and sort them manually
- Adjust the time of the first of your batch of photos with 
  "Adjust Date and time" in Photos from the "Image" menu, 
 even if the time is correct
- Select first the photo with the adjusted date, 
- the hold down the Shift key and select all photos you want 
  to set to the same date and time at once. 
- You need to select at least two photos.
- Open this script and run it by pressing the "Run" button.
- The script will copy the date from the first image 
  and set all photos to the same date, 
  and step the date by adding the increment 
  given by the variable timeIncrement.
- The script will return the last date it changed

- if you save this script as an Application 
  you can add it to the Dock and run it from there

Note - for some photos it may not be possible to change the time, 
then running "Adjust date and time" for all photos once may help. 
Photos has a bug that displays timezones incorrectly, 
so the results may look wrong, 
if the photos have been taken in different timezones.

This script has been tested in Photos version 1.0 to 4.0, 
with MacOS X 10.10.3 - macOS 10.14.2
 
© Léonie
*)


set timeIncrement to 1 -- the time increment in minutes
(* select at least 2 images in Photos *)
tell application "Photos"
	activate
	set imageSel to (get selection)
	if (imageSel is {}) or (the length of imageSel < 2) then
		error "Please select at least two images."
	else
		
		set first_image to item 1 of imageSel
		set first_date to (the date of first_image) as date
		repeat with i from 2 to count of imageSel
			
			set next_image to item i of imageSel
			set next_date to (the date of next_image) as date
			
			set time_difference to (first_date - next_date) ¬
				+ ((i - 1) * timeIncrement * minutes)
			--	return time_difference -- testing
			
			tell next_image
				set the date of next_image to (next_date + time_difference) as date
			end tell
			
		end repeat
	end if
	return "Adjusted the date and time of " & (the length of imageSel) ¬
		& " photos. The last date is " & ((the date of next_image) as date)
end tell

Moin,

wieder einmal ein Eigentor von apple?

Hab es eben ausprobiert: es wird also die Differenz des ersten Bildes zwischen Soll- und Istdatum auf die anderen ausgewählten Bilder übertragen. Sind diese an z.B. zwei aufeinanderfolgenden Tagen erstellt wurden, dann bleibt diese Differenz zwei Tage. Totaler Ro**. Dann soll es apple auch so kommunizieren!

Das fällt halt bei gleichen Ausgangsdatum nie auf.

Vor 7 Jahren (!) hattest Du genau das (oder so ähnliches) schon einmal beantwortet...

Ich habe das Skript jetzt auch in diesem Forum als Benutzertipp eingestellt:

Wie können wir das Datum und die Uhrzeit für mehrere Fotos gleichzeitig auf denselben Wert setzen?

Nicht wirklich ein Eigentor - nur die falsche Priorität. Es gibt ja zwei verschiedene Probleme, wo wir die in Stapelverarbeitung das Datum anpassen wollen, und in Fotos gibt es nur für eins davon eine Lösung, nicht für beide Probleme.

• Wenn das Datum in der Kamera falsch eingestellt war, weil wir die interne Uhr lange nicht gestellt haben oder sie die Zeit verloren hat, weil die Batterie leer war: genau für diesen Zweck haben wir in Fotos das Werkzeug, um für alle Bilder nach dem Import die falsch eingestellte Uhrzeit systematisch um denselben Betrag zu verschieben. Das ist notwendig und sollte auch weiter unterstützt werden, auch, wenn wir nur die Zeitzone auf den Aufnahmeort umstellen wollen.
• Aber mindesten so wichtig ist es, dass wir für Bilder, die wir gescannt haben oder die ohne Datum mit uns geteilt werden, allen dasselbe Datum zuweisen können müssen. Und dafür bietet Apple in Fotos keine einfache Lösung an. Das gab es bisher nur in iPhoto und nicht einmal in Apples professioneller Fotosoftware Aperture. Das Skript hatte ich ursprünglich für Aperture geschrieben.

Die Werkzeuge zur Stapelverarbeitung aus iPhoto fehlen fast völlig in Fotos, schade. Mit Apple Script können wir in Fotos nicht alle Metadaten ändern, die Schnittstelle ist sehr eingeschränkt und manche Metadaten sind schreibgeschützt oder gar nicht zugreifbar, beispielsweise die GPS Altitude, so dass wir nicht die Höhe über NN eingeben können, auch nicht die Richtung, in die die Kamera gezeigt hat.

Moin,

alle gewünschten Bilder markieren (auswählen), dann oben in Menüleiste: "Bild/Datum und Uhrzeit anpassen" wählen und Datum ändern (genau wie es in der Hilfe steht).

Moin,

willkommen im Club!